# This is an automated backup - check out https://outlands.uorazorscripts.com/script/7c8b5530-79a6-41a4-888a-634dbca497f7 for latest
# Automation by Jaseowns
## Script: Dump all reagents to a container and collect a defined amount to satchel.
## Created by: Necromunger#9178
#############################################

overhead 'Select main reagent storage.'
setvar 'sourceContainer'

@setvar! requiredReagentCount 70
@setvar! globalWaitTime 650

removelist Reagents
createlist Reagents
clearignore

// Blood Moss
@pushlist Reagents 3963
// Sulfurous Ash
@pushlist Reagents 3980
// Mandrake Root's
@pushlist Reagents 3974
// Ginseng
@pushlist Reagents 3973
// Spider's Silk
@pushlist Reagents 3981
// Black Pearl's
@pushlist Reagents 3962
// Nightshade
@pushlist Reagents 3976
// Garlic
@pushlist Reagents 3972

if findtype 'reagent satchel' self as satchel
    foreach reagentID in Reagents
        // Dump all of held reagent from satchel into storage container
        if findtype reagentID satchel as reagent and counttype reagentID satchel as reagentCount
            lift reagent reagentCount
            drop sourceContainer -1 -1 -1
            wait globalWaitTime
        endif
        
        // Pickup the amount we want from storage container
        if findtype reagentID sourceContainer as getReagent
            lift getReagent requiredReagentCount
            drop satchel -1 -1 -1
            wait globalWaitTime
        endif
    endfor
endif