# This is an automated backup - check out https://outlands.uorazorscripts.com/script/a9c2ec40-a3e0-4edf-8065-e8444b2f6608 for latest
# Automation by Jaseowns
## Script: Nacrem Auto Tame and Release
## Created by: nacrem#0
#############################################

#Buy the cheapest animal from creature broker filter by your skill.

clearsysmsg 
overhead 'Select the animal to tame:' 88
setvar! tameTarget 

// Timer
if not timerexists 'tameCooldown'
    createtimer 'tameCooldown'
    settimer 'tameCooldown' 14000 
endif

// Follow Timer
if not timerexists 'followTimer'
    createtimer 'followTimer'
endif

while not dead
    // Release strategy
    if followers > 0
        say 'all follow me'
        settimer 'followTimer' 0
        
        // Wait for pet
        while not find tameTarget ground any any 2
            if timer 'followTimer' >= 10000
                overhead 'Stuck! Releasing.' 33 tameTarget
                break
            endif
            
            overhead 'Approaching...' 68 tameTarget
            pause 1000
        endwhile

        //Release Pet When Its Closer
        menu tameTarget 9
        waitforgump 2426193729 2000 
        if gumpexists 2426193729
            gumpresponse 1
            pause 1000
        endif
        continue
    endif

    // Taming Here
    if followers == 0
        if find tameTarget ground any any 12
            if find tameTarget ground any any 2
                
                overhead 'TAMING HERE' 68 tameTarget
                
                if timer 'tameCooldown' >= 13000
                    if targetexists
                        hotkey 'Cancel Current Target'
                        pause 200
                    endif
                    
                    skill 'Animal Taming'
                    waitfortarget 1500
                    target tameTarget
                    
                    settimer 'tameCooldown' 0
                endif
                
                pause 1000
                
            else
                overhead 'out of range' 33 tameTarget
                pause 1000
            endif
        else
            overhead 'Waiting: Pet not found on screen' 34
            pause 1500
        endif
    endif
endwhile