# This is an automated backup - check out https://outlands.uorazorscripts.com/script/c04aa4d7-d848-4951-9e20-943ff659d320 for latest
# Automation by Jaseowns
## Script: Ressource Map Helper (Lumber, Mining, Skinning, Fishing)
## Created by: special_sy#0
#############################################

# Script by [DoS] Chumber
# Works with the new mapping system, just reveal the camp and start the script 
# Might have to restart after first captcha
# It will equip the right tool and start looking for the cart
setvar itemInHand 0
if findtype 'lumber map' self 2434 as myCurrentMap
    overhead "Lumber Map" 2799
    if lhandempty
        if counttype 'hatchet' self = 0
            overhead "No Hatchets found, i cant work like this!" 32
            stop
        endif
        dclicktype 'hatchet'
        # long wait for queue and stuff
        wait 2000
    endif
elseif findtype 'ore map' self 2434 as myCurrentMap
    overhead "Ore Map" 2419
    if lhandempty
        if counttype 'pickaxe' self = 0
            overhead "No pickaxes found, i cant work like this!" 32
            stop
        endif
        dclicktype 'pickaxe'
        # long wait for queue and stuff
        wait 2000
    endif
elseif findtype 'skinning map' self 2434 as myCurrentMap
    overhead "Skinning Map" 2651
    if findtype 'Elven Spellblade' self as skinningBlade
        @setvar! itemInHand skinningBlade
    else
        overhead "No skinning blade found, i cant work like this!" 32
        stop
    endif
elseif findtype 'fishing map' self 2434 as myCurrentMap
    overhead "Fishing Map" 2651
    if lhandempty
        if counttype 'fishing pole' = 0
            overhead "No fishing poles found, i cant work like this!" 32
            stop
        endif
        dclicktype 'fishing pole'
        # long wait for queue and stuff
        wait 2000
    endif
else
    overhead "Didnt find any active map!" 32
    stop
endif

if findtype 'cart|stretched hide|hanging fish' 'ground' -1 -1 7 as cart
    overhead "You found it, lets go!" 2207
    while findtype 'cart|stretched hide|hanging fish' 'ground' -1 -1 7 
        if itemInHand = 0
            hotkey 'Use Item in Hand'
        else
            dclick itemInHand
        endif
        wft 500
        target self
        wait 2000
    endwhile
    overhead "Map done" 2207
    #script 'Routines\Miner Recall'
else
    overhead "Wrong spot?" 2207
    wait 2000
endif